Mojo::URL

НАЗВАНИЕ
КРАТКИЙ ОБЗОР
ОПИСАНИЕ
АТРИБУТЫ
МЕТОДЫ
СМ. ТАКЖЕ

НАЗВАНИЕ

Mojo::URL - Uniform Resource Locator

КРАТКИЙ ОБЗОР

    use Mojo::URL;
     
    # Parse
    my $url = Mojo::URL->new(
        'http://sri:foobar@kraih.com:3000/foo/bar?foo=bar#23'
    );
    print $url->scheme;
    print $url->userinfo;
    print $url->host;
    print $url->port;
    print $url->path;
    print $url->query;
    print $url->fragment;
     
    # Build
    my $url = Mojo::URL->new;
    $url->scheme('http');
    $url->userinfo('sri:foobar');
    $url->host('kraih.com');
    $url->port(3000);
    $url->path('/foo/bar');
    $url->path('baz');
    $url->query->param(foo => 'bar');
    $url->fragment(23);
    print "$url";

ОПИСАНИЕ

Mojo::URL implements a subset of RFC 3986 and RFC 3987 for Uniform Resource Locators with support for IDNA and IRIs.

АТРИБУТЫ

Mojo::URL implements the following attributes.

authority

  my $authority = $url->authority;
  $url          = $url->authority('root:pass%3Bw0rd@localhost:8080');

Authority part of this URL.

base

    my $base = $url->base;
    $url     = $url->base(Mojo::URL->new);

Base of this URL.

fragment

    my $fragment = $url->fragment;
    $url         = $url->fragment('foo');

Fragment part of this URL.

host

    my $host = $url->host;
    $url     = $url->host('127.0.0.1');

Host part of this URL.

port

    my $port = $url->port;
    $url     = $url->port(8080);

Port part of this URL.

scheme

    my $scheme = $url->scheme;
    $url       = $url->scheme('http');

Scheme part of this URL.

userinfo

    my $userinfo = $url->userinfo;
    $url         = $url->userinfo('root:pass%3Bw0rd');

Userinfo part of this URL.

МЕТОДЫ

Mojo::URL inherits all methods from Mojo::Base and implements the following new ones.

new

    my $url = Mojo::URL->new;
    my $url = Mojo::URL->new('http://127.0.0.1:3000/foo?f=b&baz=2#foo');

Construct a new Mojo::URL object.

clone

    my $url2 = $url->clone;

Clone this URL.

ihost

    my $ihost = $url->ihost;
    $url      = $url->ihost('xn--bcher-kva.ch');

Host part of this URL in punycode format.

is_abs

    my $is_abs = $url->is_abs;

Check if URL is absolute.

parse

    $url = $url->parse('http://127.0.0.1:3000/foo/bar?fo=o&baz=23#foo');

Parse URL.

path

    my $path = $url->path;
    $url     = $url->path('/foo/bar');
    $url     = $url->path('foo/bar');
    $url     = $url->path(Mojo::Path->new);

Path part of this URL, relative paths will be appended to the existing path, defaults to a Mojo::Path object.

query

    my $query = $url->query;
    $url      = $url->query(replace => 'with');
    $url      = $url->query([merge => 'with']);
    $url      = $url->query({append => 'to'});
    $url      = $url->query(Mojo::Parameters->new);

Query part of this URL, defaults to a Mojo::Parameters object.

to_abs

    my $abs = $url->to_abs;
    my $abs = $url->to_abs(Mojo::URL->new('http://kraih.com/foo'));

Turn relative URL into an absolute one.

to_rel

    my $rel = $url->to_rel;
    my $rel = $url->to_rel(Mojo::URL->new('http://kraih.com/foo'));

Turn absolute URL into a relative one.

to_string

    my $string = $url->to_string;

Turn URL into a string.

СМ. ТАКЖЕ

Mojolicious, Mojolicious::Guides, http://mojolicio.us.